Questão Como obter a data em um arquivo em lotes em um formato previsível?


Em um arquivo de lote eu preciso extrair um mês, dia, ano do comando de data. Então usei o seguinte, que essencialmente analisa o comando Date para extrair suas sub strings em uma variável:

set Day=%Date:~3,2%
set Mth=%Date:~0,2%
set Yr=%Date:~6,4%

Isso é ótimo, mas se eu implantar esse arquivo em lote em uma máquina com configurações regionais / de país diferentes, ele falhará porque mês, dia e ano estão em locais diferentes.

Como posso extrair mês, dia e ano, independentemente do formato da data?


10


origem


Você está absolutamente restrito ao Lote? Tal coisa é muito mais simples no VBScript / WSH e / ou no PowerShell ... - Adrien
@Adrien, sim limitado ao lote - faz parte da etapa de pós-compilação do VS2008. - AngryHacker
substituindo% date% por% date: ~ 6,4% -% date: ~ 3,2% -% date: ~ 0,2% trabalhado - Enora


Respostas:


Fonte: http://ss64.com/nt/syntax-getdate.html

Método 2 (único cmd)

GetDate.cmd

@Echo off
:: Check WMIC is available
WMIC.EXE Alias /? >NUL 2>&1 || GOTO s_error

:: Use WMIC to retrieve date and time
FOR /F "skip=1 tokens=1-6" %%G IN ('WMIC Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') DO (
   IF "%%~L"=="" goto s_done
      Set _yyyy=%%L
      Set _mm=00%%J
      Set _dd=00%%G
      Set _hour=00%%H
      SET _minute=00%%I
)
:s_done

:: Pad digits with leading zeros
      Set _mm=%_mm:~-2%
      Set _dd=%_dd:~-2%
      Set _hour=%_hour:~-2%
      Set _minute=%_minute:~-2%

:: Display the date/time in ISO 8601 format:
Set _isodate=%_yyyy%-%_mm%-%_dd% %_hour%:%_minute%
Echo %_isodate%
pause

enter image description here


Método 1 (cmd + vb)

GetDate.cmd

@Echo off
For /f %%G in ('cscript /nologo getdate.vbs') do set _dtm=%%G
Set _yyyy=%_dtm:~0,4%
Set _mm=%_dtm:~4,2%
Set _dd=%_dtm:~6,2%
Set _hh=%_dtm:~8,2%
Set _nn=%_dtm:~10,2%
Echo %_yyyy%-%_mm%-%_dd%T%_hh%:%_nn%

getdate.vbs

Dim dt
dt=now
'output format: yyyymmddHHnn
wscript.echo ((year(dt)*100 + month(dt))*100 + day(dt))*10000 + hour(dt)*100 + minute(dt)

12



Ah ha, uma maneira muito legal de encontrar o pedido de data do local. ss64 tem uma comunidade bacana de usuários de cmd.exe. - Nicholi
Eu incluí os dois scripts do seu link de origem. Espero que tudo bem para você - nixda
@nixda Não tem problema, o que quer que o usuário ajude. - Tex Hex
Se você precisar manter os segundos no "Método 2" acima, adicione Set _second=00%%K ao extrair de wmic e pad com zeros à esquerda como os outros. - Tim Parenti


Windows XP e posterior

getDate.cmd

@echo off
for /f "tokens=2 delims==" %%G in ('wmic os get localdatetime /value') do set datetime=%%G

set year=%datetime:~0,4%
set month=%datetime:~4,2%
set day=%datetime:~6,2%

echo %year%/%month%/%day%

Saída

enter image description here


6





Eu sei que não é exatamente o que você pediu, mas eu uso a porta do Windows do Linux date aplicativo de um comando dentro do arquivo de lote e, em seguida, atribua o resultado a uma variável.

Eu ainda tenho que encontrar uma maneira de obter a data de forma confiável usando apenas comandos em lote.


3





Você já tentou usar NET TIME \\%ComputerName% ao invés de DATE? eu penso isso NET TIME é suposto fornecer os dados em um formato consistente, independentemente da localidade.


1



Não, isso não acontece. - AngryHacker
Interessante, eu apenas tentei, alternando entre os formatos AU e US, e net time sempre saída no formato m / d / aaaa. @AngryHacker, com quais configurações não funcionou para você? - Hydaral
Troquei francês (belga) e me deu 2011-07-27. Os EUA dão 27/07/2011 - AngryHacker


Enquanto você está certo de que o VS 2008 produz um batchfile, você pode executar praticamente qualquer programa que desejar, incluindo scripts do Powershell e outros programas.

Editar:

Aqui estão algumas perguntas semelhantes:

https://stackoverflow.com/questions/1051845/visual-studio-2008-professional-build-process https://stackoverflow.com/questions/3049369/embed-application-compilation-time-stamp

Originalmente, eu ia mudar isso para o SO. . .


1





Use este arquivo em lotes para o formato AAAA-MM-DD. Ele usa a ferramenta de instrumentação de janela que deve estar presente em todas as versões recentes do Windows para obter uma cadeia de data e hora que seja independente das configurações regionais.

Salve em um arquivo de lote no caminho (por exemplo) c: \ windows \ rdate.bat e, em seguida, acesse com uma chamada RDATE.BAT para definir a (s) variável (s). Como alternativa, copie o código no seu arquivo de lote.

Este formato de data é adequado para nomes de arquivos e log. Classifica corretamente. A variável logtime adiciona uma variável de data + hora como AAAA-MM-DD-HHMMSS adequada para uso no registro da atividade do arquivo em lote na segunda precisão.

Ajuste os formatos de data (e hora) como desejar. REM a tela ecoa em produção. Os dois números em cada seleção de texto são o índice de caractere inicial com base em zero e o número de caracteres a serem copiados, por exemplo,% datetime: ~ 0,4% recebe uma substring de 4 caracteres começando na posição 0.

echo off
rem First, get the locality-invariant datetime
for /f "tokens=2 delims==" %%I in ('wmic os get localdatetime /format:list') do set datetime=%%I
rem echo %datetime%

rem Build the reverse date string YYYY-MM-DD
set rdate=%datetime:~0,4%-%datetime:~4,2%-%datetime:~6,2%
echo rdate=%rdate%

rem Built a datetime string YYYY-MM-DD-hhmmss
set logtime=%rdate%-%datetime:~8,6% 
echo logtime=%logtime%

1



Quase o mesmo que resposta de and31415. Ambos os scripts usam wmic os get localdatetime - nixda


Isso pode ser um pouco fora do tópico, mas aqui está um arquivo .bat que eu escrevi para meus próprios backups agendados e também chamo de ações postbuild no visual studio. Espero que alguns achem útil.

Salve o seguinte em um arquivo .bat

--------------------------------------------------
**:: The following is Copyright © 2012 ShopNetNuke Corp.  All rights reserved.
::  and released under the GNU General Public License (GPLv3)**

:: The following section retrieves the current date and time and formats it into the '%var%' variable
:: This format always ensures that the Date and Time are fixed length to avoid the situation of
:: having a value of '12/ 1/2012 rather than '12/01/2012'
echo off
for /f "tokens=1-5 delims=:" %%d in ("%time%") do set var=%date:~10,4%-%date:~4,2%-%date:~7,2%-%%d-%%e
set var=%var: =0%
echo Beginning my valuable Backup Set:  Backup--%var%

:: If you wanted to request the user input a filename prefix, 
:: then we would use something similar to this
:: set /p nameprefix= Enter the file name prefix?
:: Get the Current Date and Time
::for /f "tokens=1-5 delims=:" %%d in ("%time%") do set var=%date:~10,4%-%date:~4,2%-%date:~7,2%-%%d-%%e
:: set var=%var: =0%
:: echo Beginning my valuable Backup Set:  Backup--%var%_%nameprefix%

Pause

echo Starting SQL Server Database Backup Job...
:: The following line initiates the Backup job within SqlServer Agent.
:: Change 'MyBackupNameInSqlAgent' to the name of the job you want executed
:: Change the directory paths to those relevant to your current system installation directories
:: SqlAgent will not return a value if the backup action succeed, 
:: however, in the event an error is encountered, it will be echoed onto the screen
"C:\Program Files\Microsoft SQL Server\100\Tools\Binn\sqlcmd.exe" -S SQLSERVERNAME\INSTANCENAME -Q "execute msdb.dbo.sp_start_job @job_name = 'MyBackupNameInSqlAgent'"
:: An error will be returned if the Backup job is not found or has already been triggered by another process

echo Starting My Valuable Source Code Directory Backup...

echo ...backing up files and folders in "C:\Source\MyPreciousProjectDirectory\"...
:: The following line will execute the 7zip command to create a .7z file of the directory named in 'MyPreciousProjectDirectory'
:: and tells it to put the archive in the 'MyPreciousBackupDirectory'.  The compression level will be defined by the 7zip default settings
:: The -p flag tells 7zip to password protect the archive, in this case, I've used the Date/Time portion of the filename as the password
:: remove the '-p%var%' section to remove password protection from the archive
"C:\Program Files\7-Zip\7z.exe" a -t7z C:\MyPreciousBackupDirectory\%var%\MyPreciousProject--%var%.7z -p%var% -mhe C:\Source\MyPreciousProjectDirectory\* 

echo Source Code Directory Backups complete.

echo Archiving Database Backups now...
:: The following line will execute the 7zip command to archive the Database backup.
:: The '*' could be replaced by the actual backup name.
:: The '*' indicates all files of type '.bak'
:: The -p flag tells 7zip to password protect the archive, in this case, again, I've used the Date/Time portion of the filename as the password
:: remove the '-p%var%' section to remove password protection from the archive
"C:\Program Files\7-Zip\7z.exe" a -t7z  C:\MyPreciousBackupDirectory\%var%\MyPreciousProject-Database-%var%.7z -p%var% -mhe "C:\Program Files\Microsoft SQL Server\MSSQL10.SQLDEV08\MSSQL\Backup\*.bak"

echo Database Backup Archival process complete.

:: If you wanted to place both the previous backups into one single combination archive,
:: you could do something like the following
"C:\Program Files\7-Zip\7z.exe" a -t7z C:\MyPreciousBackupDirectoryForSourceAndDatabase\%var%\MyPreciousProjectBackupSourceAndDatabase--%var%.7z -p%var% -mhe C:\Source\MyPreciousProjectDirectory\* 


echo Now attempting to copy archives to Network Server...
:: The following line will use xcopy to copy the arechives to the server backup directory and place them in a directory named by the DateTime variable %var%
xcopy /S /I /J /Y C:\MyPreciousBackupDirectory\%var% \\MyPreciousBackupServerName\SourceCode\MyPreciousServerBackupDirectory\%var%
:: Or if the combination above was used then copy that...
xcopy /S /I /J /Y C:\MyPreciousBackupDirectoryForSourceAndDatabase\%var% \\MyPreciousBackupServerName\SourceCode\MyPreciousServerBackupDirectory\%var%


echo 7z Archive files transferred to MyPreciousBackupServerName successfully
echo  ||
echo \||/
echo  \/
echo ---------------------------------------------------
echo ----- BACKUP SET "%var%" COMPLETE ------
echo ---------------------------------------------------
pause

0



tl; dr, você pode adicionar uma explicação sobre o que o script faz. porque não sai como uma solução imediatamente. Também pode ser mais útil se você puder remover os bits de código não pertinentes - Shekhar
Todo o script em lote depende do %date% e %time% variáveis, que são cientes do local e não podem ser analisadas de maneira previsível, conforme solicitado pelo OP. - and31415


Graças ao post de Shekhar, isso funciona como necessário e zero preenchimento do tempo.

@Echo Off

for /f "tokens=1-5 delims=:" %%d in ("%time%") do set var=%date:~10,4%%date:~4,2%%date:~7,2%-%%d%%e

set datetimestr=%var: =0%

set logfile=LogFile-%datetimestr%.txt

echo %logfile%

Saída: LogFile-20151113-0901.txt


0