Questão Crie um atalho de atalho / teclado para fechar a janela Notepad ++ Find Results


Eu sempre desejei que Notepad++ tinha um atalho de teclado para fechar o painel / janela Resultados da Pesquisa que aparece quando eu faço o seguinte:

  • Localizar todos em todos os documentos abertos
  • Encontre todos no documento atual
  • Encontre tudo (em vários arquivos)

Não há um construído, como discutido em essa questão, assim como este e este; F7 abre o painel ou a janela, mas não a fecha. O segundo link da questão acima sugere que Esc irá fechar o painel ou janela, mas isso não funciona para mim, pelo menos no Notepad ++> = 6.

Existe uma maneira de criar uma tecla de atalho ou atalho de teclado para fechar o painel / janela "Localizar resultados"?


2


origem




Respostas:


Existe, usando AutoHotKey. O seguinte script irá converter F7 de um atalho somente aberto a um toggle; ele abre se já não estiver aberto e fecha se for.

Aqui está o script:

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Ed Cottrell's AutoHotKey script for toggling the "Find Results" pane/window in Notepad++
; Released under the MIT License (http://opensource.org/licenses/MIT)
; Version: 1.1
; Release Date: January 15, 2014
; Released on Superuser.com: http://superuser.com/questions/700357/create-a-hotkey-keyboard-shortcut-to-close-the-notepad-find-results-window
; Also released at www.edcottrell.com/2014/01/11/toggle-find-results-window-notepad-hotkey/
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; Turn F7 into a toggle for the Notepad++ search results window; currently it shows it, but doesn't hide it.
; The $ prevents this from firing itself
*$F7::
Open := 0
SetTitleMatchMode 2  ; AHK doesn't seem to recognize the window title otherwise
; See if Notepad++ is the active window or if the undocked results window (ahk_class #32770) is the active window
If WinActive("Notepad++")
{
    ; If the results pane is open, close it
    ; Button1 is the class name for the title bar and close button of the results pane when docked
    ControlGet, OutputVar, Visible,, Button1, Notepad++
    if ErrorLevel = 0
    {
        If OutputVar > 0
        {
            ; Found it docked
            Open := 1
            ; Get the size and coordinates of the title bar and button
            ControlGetPos, X, Y, Width, Height, Button1
            ; Set the coordinates of the close button
            X := Width - 9
            Y := 5
            ; Send a click
            ControlClick, Button1,,,,, NA x%X% y%Y%
        }
    }
}
; If it is undocked, use ahk_class #32770
else If WinExist("Find result ahk_class #32770")
{
    ; Found it undocked
    Open := 1
    ; Close it
    WinClose
}
; It's not open, so open it
if Open = 0
{
    SendInput {F7}
}
return

Espero que isso ajude todos os outros que amam Notepad++!

Editado para corrigir erro na detecção de janela desencaixada.


1